度量系统服务端文件本地异地差异备份(增量备份)脚本示例

王爱东

度量产品部署好服务端后，因为服务端有各类封装加密的附件，文件等资料，为保障数据安全，除了建立高可用性的备份机制外，我们可以通过批处理脚本，结合到系统计划进行本地或异地备份，为考虑容量情况，也可以采用增量备份进行。
下面代码是一个示例批处理脚本，可以按照自己的思路编写简单而强大的服务端备份策略：

@echo off
REM ************************************************************
REM *服务端文件增量备份，每年的数据保存在DestDir中。
REM *需要设置源目录(SourceDir),备份目录（DestDir=）。
REM *如果要把服务器上的文件异地备份，要保证能磁盘映射。
REM *并启动异地备份的代码。
REM *日志有记录备份的信息。
REM *该脚本可以加入到系统计划中每天备份。

REM ************************************************************




REM ************************************************************
REM * Set Varialbes
REM ************************************************************


REM * please set date format: yyyy-MM-dd


set YearNum=%date:~0,4%
set SourceDir=C:\OAServer
set DestDir=d:\OABakDir\OAServer%YearNum%


REM *异地备份文件映射*******************************************
REM ************************************************************
REM * Remote Address
REM * net use U: \\xxx.xxx.xxx.xxx\d$ /user:Administrator "password"
REM * set DestDir=U:\OABakDir\OAServer%YearNum%
REM ************************************************************


if not exist %DestDir%  mkdir %DestDir%
set logFileName=d:\OABakDir\OAServer%date:~0,4%%date:~5,2%%date:~8,2%.log


REM ************************************************************
REM *START
REM ************************************************************


echo ***************************************** >> %logFileName%
echo START:%date% %time% >> %logFileName%
echo START COPY (%date% %time%):%SourceDir% to %DestDir% >> %logFileName%
xcopy %SourceDir%  %DestDir% /D /E /C /I /H /R /K /Y  >> %logFileName%
echo END COPY (%date% %time%):%SourceDir% to %DestDir% >> %logFileName%
echo ***************************************** >> %logFileName%


REM *删除异地映射*******************************************
REM ************************************************************
REM * net use U: /DELETE
REM ************************************************************


@echo on
Exit

张军勇

增量备份是一种较好的方案。

王爱东

增量备份：顾名思义，就是增加的就备份进来。比如一个系统中5天前的数据有10个文件，备份后，备份目录中就有10个文件；如果这5天中，增加了3个文件。那么备份后，原来10个已经备份了的文件不会重复拷贝，只需要把新增加的3个文件备份到 备份目录中。备份目录也还是完全的数据。

刘亚东

独到的

万望

楼猪这是干货，果断收藏了

张军勇

数据安全很重要。

刘亚东

谁能讲讲铮亮备份的好处

张军勇

非常有用的备份功能，围观学习、

王爱东

已经验证。好用得很。

王爱东

实现备份的效果是：增量备份，每年保留一个备份文件。另外每备份一次，就记录一个日志，详细记录了备份了那些文件。